COMMENT
 Syntax Filename = NSSQ95A.SPS
 The following SPSS 6.1 for Windows syntax statements assigns variable
 and value labels, computes various subscale and total scores,
 checks for out-of-range values, provides basic descriptive statistics,
 and lists subjects with discrepant data. 

TITLE "SCORING PROGRAM FOR 'NORBECK SOCIAL SUPPORT QUESTIONNAIRE'" .
SUBTITLE 'INCLUDING CHECK FOR DISCREPANT DATA' .

COMMENT 
 Provide the complete path to the SPSS for Windows data file that contains the
 variables of the 1995 version of the NSSQ in the GET FILE command.  If the
 data file has already been opened in SPSS, it is not necessary to GET the
 file again.

GET FILE = 'c:\subdirectory\filename.sav' .

VARIABLE  LABELS 
 IDNO 'SUBJECT  NUMBER'       
 NOLISTED 'NUMBER LISTED IN NETWORK'  
 EMO1 'EMOTIONAL SUPPORT (QUEST. 1)' 
 EMO2 'EMOTIONAL SUPPORT (QUEST. 2)' 
 EMO3 'EMOTIONAL SUPPORT (QUEST. 3)' 
 EMO4 'EMOTIONAL SUPPORT (QUEST. 4)' 
 AID5 'TANGIBLE SUPPORT (QUEST. 5)' 
 AID6 'TANGIBLE SUPPORT (QUEST. 6)' 
 DURATION 'DURATION OF RELATIONSHIP (QUEST. 7)' 
 FREQCON 'FREQUENCY OF CONTACT (QUEST. 8)' 
 LOSS 'RECENT LOSS (QUEST. 9)' 
 LOSS1 'NUMBER OF SPOUSES OR PARTNERS LOST' 
 LOSS2 'NUMBER OF FAMILY OR RELATIVES LOST' 
 LOSS3 'NUMBER OF FRIENDS LOST' 
 LOSS4 'NUMBER OF WORK OR SCHOOL ASSOCIATES LOST' 
 LOSS5 'NUMBER OF NEIGHBORS LOST' 
 LOSS6 'NUMBER OF HEALTH CARE PROVIDERS LOST' 
 LOSS7 'NUMBER OF COUNSELORS OR THERAPISTS LOST' 
 LOSS8 'NUMBER OF MINISTERS/PRIESTS/RABBIS LOST' 
 LOSS9 'NUMBER OF OTHERS LOST'  
 LOSSNO  'TOTAL NUMBER OF PERSONS LOST' 
 LOSSAMT  'AMOUNT OF SUPPORT LOST (QUEST. 9b)'.

VALUE  LABELS 
 SOU1 TO SOU24 0 'NONE' 1 'SPOUSE OR PARTNER' 2 'FAMILY OR RELATIVES'
               3 'FRIENDS' 4 'WORK/SCHOOL ASSOC' 5 'NEIGHBORS' 
               6 'HLTH CARE PROVIDERS' 7 'COUNSELOR/THERAPIST'
               8 'MINIST/PRIEST/RABBI' 9 'OTHER'/ 
 LOSS 0 'NO' 1 'YES'/ 
 LOSSAMT 0 'NONE AT ALL' 1 'A LITTLE'  2 'A MODERATE AMOUNT' 
         3 'QUITE A BIT' 4 'A GREAT  DEAL'/
 CON1 TO CON24 5 'DAILY' 4 'WEEKLY' 3 'MONTHLY' 2 'A FEW TIMES A YEAR' 
               1 'ONCE A YEAR OR LESS'.

COMMENT 
 The following commands calculate subscale and total scores. 

COMPUTE EMOSUP=EMO1+EMO2+EMO3+EMO4           /* EMOTIONAL SUPPORT
SCORE */.
COMPUTE AID=AID5+AID6                        /* TANGIBLE SUPPORT SCORE */.
COMPUTE TLFUNCT=EMOSUP+AID                   /* TOTAL FUNCTIONAL SUPPORT */.
COMPUTE TLNETWRK=NOLISTED+DURATION+FREQCON   /* TOTAL NETWORK
SCORE */.
COMPUTE TLLOSS=LOSS+LOSSNO+LOSSAMT           /* TOTAL LOSS SCORE */.

COMMENT
 The following two variables calculate Average Duration and Average
 Functional Support by dividing by the number of sources listed in the 
 network.

COMPUTE AVEDURA=DURATION/NOLISTED           /* AVERAGE DURATION SCORE
*/.
COMPUTE AVEFUNCT=TLFUNCT/NOLISTED           /* AVE. FUNCT. SUPPORT SCORE
*/.

COMMENT 
 TLFUNCT2 is a check on TLFUNCT -- ideally, the two scores should be
 identical because they are simply two different ways of calculating
 the same variable. 

COMPUTE TLFUNCT2=SUM(PER1 TO PER24)          /* CHECK SCORE FOR TLFUNCT
*/.

COMMENT 
 The following commands check for out-of-range values.  If any subject has
 out-of-range values, they are coded "1" for the variable "PROBLEM".

IF (NOLISTED <0 OR NOLISTED >24) PROBLEM=1.

DO REPEAT XSCORE=EMO1 TO AID6.
IF (XSCORE <0 OR XSCORE > NOLISTED*4) PROBLEM=2.
END REPEAT.

IF (DURATION < NOLISTED OR DURATION > NOLISTED*5) PROBLEM=3.
IF (FREQCON < NOLISTED OR FREQCON > NOLISTED*5) PROBLEM=4.

DO REPEAT XSOU=SOU1 TO SOU24/ 
          XPER=PER1 TO PER24/
          XCON=CON1 TO CON24. 
IF (XSOU <0 OR XSOU >9) PROBLEM=5.
IF (XPER <0 OR XPER >24) PROBLEM=6.
IF (XCON <1 OR XCON >5) PROBLEM=7.
END REPEAT.

VARIABLE  LABELS 
 EMOSUP 'EMOTIONAL SUPPORT SCORE'
 AID 'TANGIBLE SUPPORT SCORE' 
 TLFUNCT 'TOTAL FUNCTIONAL  SUPPORT SCORE' 
 TLNETWRK 'TOTAL NETWORK  SCORE' 
 TLLOSS 'TOTAL LOSS  SCORE'
 AVEDURA 'AVERAGE DURATION  SCORE'
 AVEFUNCT 'AVERAGE FUNCTIONAL SUPPORT  SCORE'
 TLFUNCT2 'CHECK SCORE FOR  TLFUNCT' 
 PROBLEM 'CHECK VARIABLE FOR OUT-OF-RANGE VALUES'.

VALUE  LABELS 
 PROBLEM 1 'NOLISTED OUT-OF-RANGE' 2 'EMO1 to AID6 OUT-OF-RANGE'
         3 'DURATION OUT-OF RANGE' 4 'FREQCON OUT-OF-RANGE'
         5 'SOU1 TO SOU24 OUT-0F-RANGE'
         6 'PER1 TO PER24 OUT-OF-RANGE'
         7 'CON1 TO CON24 OUT-OF-RANGE'.

COMMENT
 Provide a NEW filename for the SPSS data file that will contain the 
 original and newly created variables with the SAVE OUTFILE command.

SAVE OUTFILE = 'c:\subdirectory\filesub1.sav' /COMPRESSED.

COMMENT 
 The following two commands provide basic descriptive statistics. 

FREQUENCIES VAR=PROBLEM NOLISTED LOSS LOSSNO LOSSAMT.

DESCRIPTIVES VAR=NOLISTED TO FREQCON LOSS1 TO LOSSAMT EMOSUP TO
TLFUNCT2.

COMMENT 
 The last set of commands lists subjects with discrepant data. 

FILTER BY PROBLEM.
LIST VAR=IDNO  NOLISTED TO  FREQCON.
LIST VAR=IDNO  SOU1 TO  SOU24.
LIST VAR=IDNO  PER1 TO  PER24.
LIST VAR=IDNO  CON1 TO  CON24.
FILTER OFF.